播放.Rm/.rmvb格式的视频用什么控件
请问VFP播放.Rm/.rmvb格式的视频用什么控件?
[解决办法]
要播放某种格式的视频关键不是使用什么播放器，而是机器上有没有安装 rm 视频解码器
只要有对应的解码器，任何视频播放器都可以播放，不同的只是播放品质和解码速度
rm 最权威的当然是 RealOne，另外能播放这种格式的播放器很多，大多都已内置了 rm 解码器
用 Media Player 也可以播放，只要下载一个 Realone 解码器 For Windows Media Player 就可以了
[解决办法]
安装 Windows Media Player 及 Realone 解码器 For Windows Media Player
然后用 VFP 调用 Windows Media Player 播放
*-- 作者：dkfdtf
Local cName, oForm
m.cName = Sys(2015)
_Screen.AddProperty( m.cName, Newobject( 'PlayerForm' ))
m.oForm = Evaluate( '_Screen.' + m.cName )
m.oForm.Name = m.cName
m.oForm.Show()
Return
Define Class PlayerForm As Form
Width = 400
Height = 300
AutoCenter = .T.
*!* AlwaysOnTop = .T. && 总在最前面
AllowOutput = .F.
ShowWindow = 2
Caption = '简易媒体播放器'
DoCreate = .T.
Add Object player As OleControl With ;
OleClass = 'WMPlayer.ocx.7'
Procedure Init
This.Resize()
This.player.url = Getfile( 'avi;wmv;mpg;asf;rmvb' )
Endproc
Procedure Destroy
If Pemstatus( _Screen, This.Name, 5 )
Removeproperty( _Screen, This.Name )
Endif
Endproc
Procedure Resize
This.player.Move( 0, 0, This.Width, This.Height )
Endproc
Procedure player.Init
With This
.uiMode = 'full' && full / mini / none
.StretchToFit = .T. && 自动缩放
.Settings.AutoStart = .F. && 自动开始播放
.Settings.Volume = 100 && 音量
Endwith
Endproc
Procedure player.StatusChange
Thisform.Resize()
Endproc
Enddefine
