王爽汇编 实验七的问题
assume cs:code,ds:data,es:table,ss:stack
data segment
db '1975','1976','1977','1994','1995'
dd 16,22,382,4649000,5937000
dw 3,7,9,15257,17800
data ends
table segment
db 5 dup ('year summ ne ?? ')
table ends
stack segment
db 0,0,0,0
stack ends
code segment
start:mov ax,data
mov ds,ax
mov ax,table
mov es,ax
mov bx,0
mov si,0
mov cx,5
s:push cx
mov di,0
mov cx,2
s1:mov ax,[si]
mov es:[bx+di],ax
add si,2
add di,2;年份
loop s1
pop cx
add bx,16
loop s
mov bx,0
mov cx,5
s3:push cx
mov di,4
mov al,32
mov es:[bx+di],al
inc di
mov cx,2
s2:mov ax,[si]
mov es:[bx+di],ax
add si,2
add di,2;收入
loop s2
add si,80
mov al,32
mov es:[bx+di],al
mov ax,[si]
mov es:[bx+di],ax;人数 [color=#FF0000][/color]为什么这里就开始不正常了呢？为什么不能正常传递值了呢？
mov al,32
mov es:[bx+di],al
inc di
mov dx,es:[bx+7]
mov ax,es:[bx+5]
div word ptr es:[bx+10]
mov es:[bx+di],ax;人均收入
inc di
mov al,32
mov es:[bx+di],al
pop cx
add bx,16
sub si,81
loop s3
mov ax,4c00h
int 21h
code ends
end start
[color=#FF0000][/color]
[解决办法]
assume cs:codesg,ds:data,es:table
data segment
db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
db '1993','1994','1995'
;以上是表示21年的21个字符串
dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514
dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000
;以上是表示21年公司总收的21个dword型数据
dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
dw 11542,14430,45257,17800
;以上是表示21年公司雇员人数的21个word型数据
data ends
table segment
db 21 dup('year summ ne ?? ')
table ends
codesg segment
start:
mov ax,data
mov ds,ax
mov ax,table
mov es,ax
mov bx,0
mov si,0
mov di,0
mov cx,21
s: ;进入循环
mov al,[bx]
mov es:[di],al
mov al,[bx+1]
mov es:[di+1],al
mov al,[bx+2]
mov es:[di+2],al
mov al,[bx+3]
mov es:[di+3],al
;以上8句的作用是存放年份
mov ax,54h[bx] ;第一个'年收入'的段基址为54H
mov dx,56h[bx]
mov es:5h[di],ax
mov es:7h[di],dx
;以上4句的作用是存放公司总收入
mov ax,0A8h[si] ;第一个'人数'的段基址为0A8H
mov es:0Ah[di],ax
;以上2句是存放公司的人数
mov ax,54h[bx]
div word ptr ds:0A8h[si]
mov es:0dh[di],ax
;以上3句是存放人均收入
add bx,4
add si,2
add di,16
;以上3句是为下一次循环时存放数据做准备
;3个寄存器递增的速度决定了所要存取的数据的位置的偏移地址
loop s ;跳到标号s处
mov ax,4c00h
int 21h
codesg ends
end start
楼主仔细看下吧，编译通过的程序。
[解决办法]
assume cs:code,ds:data,es:table
data segment
db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
db '1993','1994','1995'
dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514
dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000
dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
dw 11542,14430,15257,17800
data ends
table segment
db 21 dup('year summ ne ?? ')
table ends
code segment
start:mov ax,data;源数据段地址
mov ds,ax
mov ax,table;目标数据段地址
mov es,ax
mov bx,0
mov si,0
mov di,0
mov cx,21;设置循环次数
s:mov ax,[si];把年份写入table
mov es:[bx],ax
mov ax,2h[si]
mov es:[bx].2h,ax
mov ax,0a8h[di];把人数写入table
mov es:[bx].0ah,ax
mov ax,54h[si];把收入写入table
mov es:[bx].5h,ax
mov dx,56h[si]
mov es:[bx].7h,dx
div word ptr es:[bx].0ah;求人均收入(取整数)
mov es:[bx].0dh,ax
add bx,16
add si,4
add di,2
loop s
mov ah,4ch
int 21h
code ends
end start
——————————————————————
