求帮写一个SQL函数，15身份证转18位解决办法

求帮写一个SQL函数，15身份证转18位
大侠们，我有一列是15位身份证的，我想写一个SQL函数把15位的转换成18位，大侠们注意，不是单纯的再后面加XXX喔，，，

求大侠们帮写一个函数： 15位的做参数，  然后返回一个18位身份证号的字符串。
[解决办法]

--将15位身份证升级成18位的用户定义函数
CREATE FUNCTION ID15TO18 (@id15 char(15)) 
RETURNS CHAR(18) AS 
BEGIN 
   DECLARE @ID18 CHAR(18)
   
   DECLARE @S1 AS INTEGER
   DECLARE @S2 AS INTEGER
   DECLARE @S3 AS INTEGER
   DECLARE @S4 AS INTEGER
   DECLARE @S5 AS INTEGER
   DECLARE @S6 AS INTEGER
   DECLARE @S7 AS INTEGER
   DECLARE @S8 AS INTEGER
   DECLARE @S9 AS INTEGER
   DECLARE @S10 AS INTEGER
   DECLARE @S11 AS INTEGER
   DECLARE @S12 AS INTEGER
   DECLARE @S13 AS INTEGER
   DECLARE @S14 AS INTEGER
   DECLARE @S15 AS INTEGER
   DECLARE @S16 AS INTEGER
   DECLARE @S17 AS INTEGER
   DECLARE @S18 AS INTEGER
   
   SET @S1 = SUBSTRING(@ID15,1,1)
   SET @S2 = SUBSTRING(@ID15,2,1)
   SET @S3 = SUBSTRING(@ID15,3,1)
   SET @S4 = SUBSTRING(@ID15,4,1)
   SET @S5 = SUBSTRING(@ID15,5,1)
   SET @S6 = SUBSTRING(@ID15,6,1)
   SET @S7 = 1
   SET @S8 = 9
   SET @S9 = SUBSTRING(@ID15,7,1)
   SET @S10 = SUBSTRING(@ID15,8,1)
   SET @S11 = SUBSTRING(@ID15,9,1)
   SET @S12 = SUBSTRING(@ID15,10,1)
   SET @S13 = SUBSTRING(@ID15,11,1)
   SET @S14 = SUBSTRING(@ID15,12,1)
   SET @S15 = SUBSTRING(@ID15,13,1)
   SET @S16 = SUBSTRING(@ID15,14,1)
   SET @S17 = SUBSTRING(@ID15,15,1)
   
   SET @S18 = ( (@S1*7) + (@S2*9) + (@S3*10) + (@S4*5) + (@S5*8) + 
   (@S6*4) + (@S7*2) + (@S8*1) + (@S9*6) + (@S10*3) + 
   (@S11*7) + (@S12*9) + (@S13*10) + (@S14*5) + (@S15*8) + 
   (@S16*4) + (@S17*2) ) % 11
   
   SET @ID18 = SUBSTRING(@ID15,1,6) + '19' + SUBSTRING(@ID15,7,9) + 
                 CASE 
                     WHEN @S18 = 0 THEN '1'
                     WHEN @S18 = 1 THEN '0'
                     WHEN @S18 = 2 THEN 'X'
                     WHEN @S18 = 3 THEN '9'
                     WHEN @S18 = 4 THEN '8'
                     WHEN @S18 = 5 THEN '7'
                     WHEN @S18 = 6 THEN '6'
                     WHEN @S18 = 7 THEN '5'
                     WHEN @S18 = 8 THEN '4'
                     WHEN @S18 = 9 THEN '3'
                     WHEN @S18 = 10 THEN '2'
                 END
    
 
    RETURN @ID18
END 
GO



--调用函数
update 
    表
set 
    身份证号 = dbo.ID15TO18(身份证号)
where
    LEN(身份证号) = 15

[解决办法]
http://blog.csdn.net/maco_wang/article/details/6261545
[解决办法]
http://blog.csdn.net/smahorse/article/details/7892569貌似都是一样的
[解决办法]

引用叶子版主的文章：

【叶子函数分享十四】将身份证的15位号码升级为18位 

http://blog.csdn.net/maco_wang/article/details/6261545
[解决办法]
精简一下，并且自动判断加19还是20

--将15位身份证升级成18位
declare @id15 char(15)='222222830604321'
-- 判断加19还是20
declare @yy char(2)=CONVERT(char(2),DATEPART(yy,getdate()) / 100- case when CONVERT(int,substring(@id15,7,2))<=DATEPART(yy,getdate()) % 100 then 0 else 1 end)
declare @id17 char(17)=substring(@id15,1,6)+@yy+substring(@id15,7,9)
declare @tt table ( id int identity, n1 int, n2 int)
insert into @tt(n2) values(7),(9),(10),(5),(8),(4),(2),(1),(6),(3),(7),(9),(10),(5),(8),(4),(2)
update @tt set n1=SUBSTRING(@ID17,id,1)
select @id17 + SUBSTRING('10X98765432', (select SUM(n1*n2)%11+1 from @tt), 1)

查看更多 下一篇