VB如何执行Telnet命令（不出现命令提示符窗口）
不希望用生成批处理BAT后用Shell去调用，然后隐藏 提示符窗口 的做法！
Telnet进去后，还得执行3个命令，用VBS脚本我会做，但是运行了还是会出现 提示符窗口
我希望做出来得结果是：能在VB的TEXT文本框里看到执行后返回的数据，全部过程不需要调用到CMD提示符窗口
Telnet 命令如下：
-----------------------------------------------------
telnet members.3322.org 80
GET /dyndns/update?system=dyndns&hostname=myDB.3322.org&wildcard=OFF&offline=NO HTTP/1.1
Host: members.3322.org
Authorization: Basic bXlEQjoxMjM0NTY=
------------------------------------------------------
VBS脚本是这样的：
--------------------------------------------------
Set WshShell = CreateObject("WScript.Shell")
WshShell.Run "telnet members.3322.org 80"
WScript.Sleep(1200)
WshShell.SendKeys "GET /dyndns/update?system=dyndns&hostname=myDB.3322.org&wildcard=OFF&offline=NO HTTP/1.1{enter}"
WScript.Sleep(500)
WshShell.SendKeys "Host: members.3322.org{enter}"
WScript.Sleep(500)
WshShell.SendKeys "Authorization: Basic bXlEQjoxMjM0NTY={enter}"
WScript.Sleep(500)
WshShell.SendKeys "{enter}"
---------------------------------------------------
希望高手指教！！！！！
[最优解释]
一个text1控件和一个winsock1控件
大致代码就这样子
Option Explicit
Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
Private Sub Form_Load()
Winsock1.Protocol = sckTCPProtocol
Winsock1.Connect "members.3322.org", 80
End Sub
Private Sub Winsock1_Connect()
Dim Str As String
Str = "GET /dyndns/update?system=dyndns&hostname=myDB.3322.org&wildcard=OFF&offline=NO HTTP/1.1 " & vbCrLf
Str = Str & "Host: members.3322.org" & vbCrLf
Str = Str & "Authorization: Basic bXlEQjoxMjM0NTY=" & vbCrLf
Winsock1.SendData Str
End Sub
Private Sub Winsock1_DataArrival(ByVal bytesTotal As Long)
Dim Data As String
Winsock1.GetData Data
Text1.Text = Data
End Sub
Set WshShell = Wscript.CreateObject("WScript.Shell")
a = WshShell.Run ("telnet members.3322.org 80" , 0)
WScript.Sleep(1200)
WshShell.SendKeys "GET /dyndns/update?system=dyndns&hostname=myDB.3322.org&wildcard=OFF&offline=NO HTTP/1.1{enter}"
WScript.Sleep(500)
WshShell.SendKeys "Host: members.3322.org{enter}"
WScript.Sleep(500)
WshShell.SendKeys "Authorization: Basic bXlEQjoxMjM0NTY={enter}"
WScript.Sleep(500)
WshShell.SendKeys "{enter}"
Option Explicit
Option Base 0
'Code written by JoshT. Use at your own risk
Private Declare Function CreateProcess Lib "kernel32" Alias "CreateProcessA" _
(ByVal lpApplicationName As String, _
ByVal lpCommandLine As String, _
lpProcessAttributes As SECURITY_ATTRIBUTES, _
lpThreadAttributes As SECURITY_ATTRIBUTES, _
ByVal bInheritHandles As Long, _
ByVal dwCreationFlags As Long, _
lpEnvironment As Any, _
ByVal lpCurrentDirectory As String, _
lpStartupInfo As STARTUPINFO, _
lpProcessInformation As PROCESS_INFORMATION) As Long
Private Declare Function CloseHandle Lib "kernel32.dll" (ByVal hObject As Long) As Long
Private Declare Function ReadFile Lib "kernel32" (ByVal hFile As Long, _
lpBuffer As Any, ByVal nNumberOfBytesToRead As Long, lpNumberOfBytesRead As Long, _
lpOverlapped As Long) As Long
Private Declare Function WaitForSingleObject Lib "kernel32" _
(ByVal hHandle As Long, ByVal dwMilliseconds As Long) As Long
Private Declare Function CreatePipe Lib "kernel32" (phReadPipe As Long, _
phWritePipe As Long, lpPipeAttributes As SECURITY_ATTRIBUTES, _
ByVal nSize As Long) As Long
Private Type STARTUPINFO
cb As Long
lpReserved As String
lpDesktop As String
lpTitle As String
dwX As Long
dwY As Long
dwXSize As Long
dwYSize As Long
dwXCountChars As Long
dwYCountChars As Long
dwFillAttribute As Long
dwFlags As Long
wShowWindow As Integer
cbReserved2 As Integer
lpReserved2 As Long
hStdInput As Long
hStdOutput As Long
hStdError As Long
End Type
Private Type PROCESS_INFORMATION
hProcess As Long
hThread As Long
dwProcessId As Long
dwThreadId As Long
End Type
Private Type SECURITY_ATTRIBUTES
nLength As Long
lpSecurityDescriptor As Long
bInheritHandle As Long
End Type
Private Const NORMAL_PRIORITY_CLASS As Long = &H20&
Private Const STARTF_USESTDHANDLES As Long = &H100&
Private Const STARTF_USESHOWWINDOW As Long = &H1&
Private Const SW_HIDE As Long = 0&
Private Const INFINITE As Long = &HFFFF&
Public Function RunCommand(CommandLine As String) As String
Dim si As STARTUPINFO 'used to send info the CreateProcess
Dim pi As PROCESS_INFORMATION 'used to receive info about the created process
Dim retval As Long 'return value
Dim hRead As Long 'the handle to the read end of the pipe
Dim hWrite As Long 'the handle to the write end of the pipe
Dim sBuffer(0 To 63) As Byte 'the buffer to store data as we read it from the pipe
Dim lgSize As Long 'returned number of bytes read by readfile
Dim sa As SECURITY_ATTRIBUTES
Dim strResult As String 'returned results of the command line
'set up security attributes structure
With sa
.nLength = Len(sa)
.bInheritHandle = 1& 'inherit, needed for this to work
.lpSecurityDescriptor = 0&
End With
'create our anonymous pipe an check for success
' note we use the default buffer size
' this could cause problems if the process tries to write more than this buffer size
retval = CreatePipe(hRead, hWrite, sa, 0&)
If retval = 0 Then
Debug.Print "CreatePipe Failed"
RunCommand = ""
Exit Function
End If
'set up startup info
With si
.cb = Len(si)
.dwFlags = STARTF_USESTDHANDLES Or STARTF_USESHOWWINDOW 'tell it to use (not ignore) the values below
.wShowWindow = SW_HIDE
' .hStdInput = GetStdHandle(STD_INPUT_HANDLE)
.hStdOutput = hWrite 'pass the write end of the pipe as the processes standard output
' .hStdError = GetStdHandle(STD_ERROR_HANDLE)
End With
'run the command line and check for success
retval = CreateProcess(vbNullString, _
CommandLine & vbNullChar, _
sa, _
sa, _
1&, _
NORMAL_PRIORITY_CLASS, _
ByVal 0&, _
vbNullString, _
si, _
pi)
If retval Then
'wait until the command line finishes
' trouble if the app doesn't end, or waits for user input, etc
WaitForSingleObject pi.hProcess, INFINITE
'read from the pipe until there's no more (bytes actually read is less than what we told it to)
Do While ReadFile(hRead, sBuffer(0), 64, lgSize, ByVal 0&)
'convert byte array to string and append to our result
strResult = strResult & StrConv(sBuffer(), vbUnicode)
'TODO = what's in the tail end of the byte array when lgSize is less than 64???
Erase sBuffer()
If lgSize <> 64 Then Exit Do
Loop
'close the handles of the process
CloseHandle pi.hProcess
CloseHandle pi.hThread
Else
Debug.Print "CreateProcess Failed" & vbCrLf
End If
'close pipe handles
CloseHandle hRead
CloseHandle hWrite
'return the command line output
RunCommand = Replace(strResult, vbNullChar, "")
End Function
Private Sub about_Click()
frmAbout.Show
End Sub
Private Sub begin_Click()
Dim i As Integer
Dim p As String
Dim q As String
Dim com As String
For i = 1 To 400
p = "c:\test\(" + Str(i) + ").html"
q = Str(i) + ".html"
com = "rename " + p + " " + q
Text2.Text = com
Text1.Text = Text1.Text + RunCommand(com)
'Text1.Text = RunCommand(Text2.Text)
Next i
End Sub