vb报表预览显示提示;报表宽度大于纸张宽度?
我的程序是标签打印系统,有个报表要打印,但设置的报表在我自己的电脑上可以显示 ,也可以运行,但在客户的电脑上报表显示就提示:报表宽度大于纸张宽度,为什么了?我已经对报表页面设置横向打印了,同时标签打印的页面是纵向的,在我电脑显示完全正确.(客户的电脑的显示器和我的一样的,但是液晶的而已,操作系统也一样).要怎么解决了?谢谢高手帮忙!
[解决办法]
会的，你可以在代码中加入设置打印机，给你一个模块
Option Explicit
Public Enum PrinterOrientationConstants
OrientPortrait = 1 '肖像, 人像 | .
OrientLandscape = 2 '风景, 山水画, 地形, 前景 ---- .
End Enum
Private Type PRINTER_DEFAULTS
pDataType As String
pDevMode As Long
DesiredAccess As Long
End Type
Private Type PRINTER_INFO_2
pServerName As Long
pPrinterName As Long
pShareName As Long
pPortName As Long
pDriverName As Long
pComment As Long
pLocation As Long
pDevMode As Long
pSepFile As Long
pPrintProcessor As Long
pDataType As Long
pParameters As Long
pSecurityDescriptor As Long
Attributes As Long
Priority As Long
DefaultPriority As Long
StartTime As Long
UntilTime As Long
Status As Long
cJobs As Long
AveragePPM As Long
End Type
Public Const DMPAPER_A5 = 11
Private Const DM_IN_BUFFER As Long = 8
Private Const DM_OUT_BUFFER As Long = 2
Private Const DM_ORIENTATION As Long = &H1
Private Const DM_PAPERSIZE = &H2&
Private Const PRINTER_ACCESS_ADMINISTER As Long = &H4
Private Const PRINTER_ACCESS_USE As Long = &H8
Private Const STANDARD_RIGHTS_REQUIRED As Long = &HF0000
Private Const PRINTER_ALL_ACCESS = (STANDARD_RIGHTS_REQUIRED Or PRINTER_ACCESS_ADMINISTER Or PRINTER_ACCESS_USE)
Public Enum Modifypage
Orientation = 1
ModifySize = 2
End Enum
'Private Declare Sub CopyMemory Lib "kernel32 " Alias "RtlMoveMemory " (hpvDest As Any, hpvSource As Any, ByVal cbCopy As Long)
Private Declare Function OpenPrinter Lib "winspool.drv " Alias "OpenPrinterA " (ByVal pPrinterName As String, phPrinter As Long, pDefault As Any) As Long
Private Declare Function ClosePrinter Lib "winspool.drv " (ByVal hPrinter As Long) As Long
Private Declare Function DocumentProperties Lib "winspool.drv " Alias "DocumentPropertiesA " (ByVal hWnd As Long, ByVal hPrinter As Long, ByVal pDeviceName As String, pDevModeOutput As Any, pDevModeInput As Any, ByVal fMode As Long) As Long
Private Declare Function GetPrinter Lib "winspool.drv " Alias "GetPrinterA " (ByVal hPrinter As Long, ByVal Level As Long, pPrinter As Any, ByVal cbBuf As Long, pcbNeeded As Long) As Long
Private Declare Function SetPrinter Lib "winspool.drv " Alias "SetPrinterA " (ByVal hPrinter As Long, ByVal Level As Long, pPrinter As Any, ByVal Command As Long) As Long
Function SetDefaultPrinterOrientation(ByVal eOrientation As PrinterOrientationConstants, _
Optional Str_Type As Modifypage = Orientation, _
Optional PaperSize As PrinterObjectConstants = vbPRPSA4, _
Optional NotShowInfo As Boolean) As Boolean
Dim bDevMode() As Byte: Dim bPrinterInfo2() As Byte: Dim hPrinter As Long
Dim lResult As Long: Dim nSize As Long: Dim sPrnName As String
Dim dm As DEVMODE_TYPE: Dim pd As PRINTER_DEFAULTS
Dim pi2 As PRINTER_INFO_2
On Error GoTo ErrPrt
' 获取默认打印机的设备名称
sPrnName = Printer.DeviceName
' 由于要调用SetPrinter，所以
' 如果是在NT下就要求PRINTER_ALL_ACCESS
pd.DesiredAccess = PRINTER_ALL_ACCESS
' 获取打印机句柄
If OpenPrinter(sPrnName, hPrinter, pd) Then
' 获取PRINTER_INFO_2结构要求的字节数
Call GetPrinter(hPrinter, 2&, 0&, 0&, nSize)
ReDim bPrinterInfo2(1 To nSize) As Byte
lResult = GetPrinter(hPrinter, 2, bPrinterInfo2(1), nSize, nSize)
Call CopyMemory(pi2, bPrinterInfo2(1), Len(pi2))
nSize = DocumentProperties(0&, hPrinter, sPrnName, 0&, 0&, 0)
ReDim bDevMode(1 To nSize)
If pi2.pDevMode Then
Call CopyMemory(bDevMode(1), ByVal pi2.pDevMode, Len(dm))
Else
Call DocumentProperties(0&, hPrinter, sPrnName, bDevMode(1), 0&, DM_OUT_BUFFER)
End If
Call CopyMemory(dm, bDevMode(1), Len(dm))
With dm ' 设置新的走向
Select Case Str_Type
Case Orientation '改变方向
.dmOrientation = eOrientation
.dmFields = DM_ORIENTATION
Case ModifySize '改变纸张大小
.dmPaperSize = PaperSize
.dmFields = DM_PAPERSIZE '必须，否则无法设置纸张大小
End Select
End With
Call CopyMemory(bDevMode(1), dm, Len(dm))
Call DocumentProperties(0&, hPrinter, sPrnName, _
bDevMode(1), bDevMode(1), DM_IN_BUFFER Or _
DM_OUT_BUFFER)
pi2.pDevMode = VarPtr(bDevMode(1))
lResult = SetPrinter(hPrinter, 2, pi2, 0&)
Call ClosePrinter(hPrinter)
SetDefaultPrinterOrientation = True
Else
SetDefaultPrinterOrientation = False
End If
Exit Function
ErrPrt: If NotShowInfo Then MsgBox Err.Description
End Function
在打开报表之前打开设置纸张
Call SetDefaultPrinterOrientation(vbPRORPortrait, ModifySize, , True) '调整大小为A4 '
Call SetDefaultPrinterOrientation(vbPRORPortrait, 1) '调整为纵向 '
Call SetDefaultPrinterOrientation(OrientLandscape, 1) '调整为横向 '
[解决办法]
怎么设置啊?在公司自己电脑可以打印的,但在客户的电脑上就出错了,而且设置打印纸的话,那个标签打印的会不会也成横向打印了?
------------------------------------------
你首先要指定打印机，然后在“开始/设置/打印机和传真”，右键你要打印报表的打印机，选择“属性”，在“打印首选项”和“设备设置”中指定纸张规格，不同打印机会略有不同，多试试就知道了。
